nix-update-git/flake.nix at main · yuxqiu/nix-update-git · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
{
  description = "Update git references in Nix flake files and Nix expressions";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
  };

  outputs =
    { self, nixpkgs }:
    let
      cargoToml = fromTOML (builtins.readFile ./Cargo.toml);
      supportedSystems = [
        "x86_64-linux"
        "aarch64-linux"
        "x86_64-darwin"
        "aarch64-darwin"
      ];
      forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
      pkgsFor = system: import nixpkgs { inherit system; };
    in
    {
      packages = forAllSystems (
        system:
        let
          pkgs = pkgsFor system;
        in
        {
          nix-update-git =
            let
              runtimeDeps = with pkgs; [
                git
              ];
            in
            pkgs.rustPlatform.buildRustPackage {
              pname = cargoToml.package.name;
              version = cargoToml.package.version;
              src = pkgs.lib.cleanSource self;
              cargoLock.lockFile = ./Cargo.lock;

              NIX_UPDATE_GIT_HASH = self.shortRev or "unknown";

              nativeBuildInputs = with pkgs; [
                makeWrapper
                git
              ];

              postInstall = ''
                wrapProgram $out/bin/nix-update-git \
                  --prefix PATH : ${pkgs.lib.makeBinPath runtimeDeps}
              '';

              cargoTestFlags = [ "--no-default-features" ];

              meta = with pkgs.lib; {
                description = "Update git references in Nix flake files and Nix expressions";
                homepage = "https://github.com/yuxqiu/nix-update-git";
                license = licenses.mit;
                mainProgram = "nix-update-git";
              };
            };
          default = self.packages.${system}.nix-update-git;
        }
      );

      devShells = forAllSystems (
        system:
        let
          pkgs = pkgsFor system;
        in
        {
          default = pkgs.mkShell {
            packages = with pkgs; [
              rustc
              cargo
              clippy
              rustfmt
              rust-analyzer
              cargo-watch
              git
            ];
          };
        }
      );

      overlays.default = final: prev: {
        nix-update-git = self.packages.${prev.system}.default;
      };
    };
}