MavenDeployer/settings.gradle.kts at main · deepmedia/MavenDeployer · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
pluginManagement {

    repositories {
        gradlePluginPortal()
        mavenCentral()
        mavenLocal()

        val props = java.util.Properties().apply {
            file("local.properties")
                .takeIf { it.exists() }
                ?.inputStream()
                ?.use { load(it) }
        }
        val user: String? = "GHUB_USER".let { props.getProperty(it) ?: System.getenv(it) }
        val token: String? = "GHUB_PERSONAL_ACCESS_TOKEN".let { props.getProperty(it) ?: System.getenv(it) }
        if (!user.isNullOrEmpty() && !token.isNullOrEmpty()) {
            maven {
                url = uri("https://maven.pkg.github.com/deepmedia/MavenDeployer")
                credentials.username = user
                credentials.password = token
            }
        }
    }
}

dependencyResolutionManagement {
    @Suppress("UnstableApiUsage")
    repositories {
        mavenCentral()
        google()
    }
}

include(":deployer")