build.gradle

plugins {
    id 'java'
    id "com.github.spotbugs" version '4.7.0'
    id "com.adarshr.test-logger" version "2.1.1" apply false
    id 'org.cadixdev.licenser' version '0.5.1'
    id 'pl.allegro.tech.build.axion-release' version '1.13.3'
}

scmVersion.tag.prefix = ""

allprojects {
    apply from: "${rootDir}/gradle/dependencies.gradle"

    group 'gg.solarmc.velocity'
    project.version = scmVersion.version

    ext {
        // dependency versions
        adventureVersion = '4.9.1'
        junitVersion = '5.7.0'
        slf4jVersion = '1.7.30'
        log4jVersion = '2.15.0'
        nettyVersion = '4.1.67.Final'
        guavaVersion = '30.1.1-jre'
        checkerFrameworkVersion = '3.6.1'
        configurateVersion = '3.7.2'

        getCurrentShortRevision = {
            new ByteArrayOutputStream().withStream { os ->
                exec {
                    executable = "git"
                    args = ["rev-parse", "HEAD"]
                    standardOutput = os
                }
                return os.toString().trim().substring(0, 8)
            }
        }
    }

    repositories {
        mavenCentral()

        // Solar repo
        maven { url "https://repo.solarmc.gg/mvn" }
    }

    dependencies {
        modules {
            module("javax.inject:javax.inject") {
                replacedBy("jakarta.inject:jakarta.inject-api")
            }
            module("javax.activation:javax.activation-api") {
                replacedBy("com.sun.activation:javax.activation")
            }
            module("com.sun.activation:jakarta.activation") {
                replacedBy("com.sun.activation:javax.activation")
            }
        }
    }

    tasks.withType(com.github.spotbugs.snom.SpotBugsTask) {
        reports {
            html {
                enabled = true
                destination = file("$buildDir/reports/spotbugs/main/spotbugs.html")
                stylesheet = 'fancy-hist.xsl'
            }
        }
    }
}