native-list/build.gradle.kts at main · Over-Run/native-list · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
import org.jreleaser.model.Active

plugins {
    `java-library`
    idea
    `maven-publish`
    id("org.jreleaser") version "1.23.0"
}

group = "io.github.over-run"
version = "1.1.0"

repositories {
    mavenCentral()
}

dependencies {
    api("org.jspecify:jspecify:1.0.0")

    testImplementation(platform("org.junit:junit-bom:6.0.2"))
    testImplementation("org.junit.jupiter:junit-jupiter")
    testRuntimeOnly("org.junit.platform:junit-platform-launcher")
}

tasks.test {
    useJUnitPlatform()
    jvmArgs("--enable-native-access=ALL-UNNAMED")
}

tasks.withType<Javadoc> {
    options {
        jFlags("-Duser.language=en")
    }
}

sourceSets {
    main {
        java {
            srcDirs("src/main/generated")
        }
    }

}

idea {
    module {
        generatedSourceDirs.add(file("src/main/generated"))
    }
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(25)
    }

    withSourcesJar()
    withJavadocJar()
}

tasks.withType<JavaCompile> {
    options.release = 25
}

publishing.repositories {
    maven {
        name = "staging"
        url = uri(layout.buildDirectory.dir("staging-deploy"))
    }
}

publishing.publications {
    register<MavenPublication>("mavenPublication") {
        groupId = project.group.toString()
        artifactId = "native-list"
        version = project.version.toString()
        from(components["java"])
        pom {
            name = "Native List"
            description = "Native list is a resizable array backed by memory segment."
            url = "https://github.com/Over-Run/native-list"
            licenses {
                license {
                    name = "MIT License"
                    url = "https://raw.githubusercontent.com/Over-Run/native-list/refs/heads/main/LICENSE"
                }
            }
            developers {
                developer {
                    name = "squid233"
                    organization = "Overrun Organization"
                    organizationUrl = "https://github.com/Over-Run"
                }
            }
            scm {
                connection = "scm:git:git://github.com/Over-Run/native-list.git"
                developerConnection = "scm:git:ssh://github.com:Over-Run/native-list.git"
                url = "https://github.com/Over-Run/native-list"
            }
        }
    }
}

jreleaser {
    signing {
        pgp {
            active = Active.ALWAYS
            armored = true
        }
    }
    deploy {
        maven {
            mavenCentral {
                mavenCentral {
                    register("release-deploy") {
                        active = Active.RELEASE
                        url = "https://central.sonatype.com/api/v1/publisher"
                        stagingRepository("build/staging-deploy")
                    }
                }
                nexus2 {
                    register("snapshot-deploy") {
                        active = Active.SNAPSHOT
                        snapshotUrl = "https://central.sonatype.com/repository/maven-snapshots/"
                        applyMavenCentralRules = true
                        snapshotSupported = true
                        closeRepository = true
                        releaseRepository = true
                        stagingRepository("build/staging-deploy")
                    }
                }
            }
        }
    }
}